User:Lindenb/Notebook/UMR915/20110131

20110128        Top        20110201       

Project 'B'

merging files

interactome for project 'B'

tried to open BIOGRID human in cytoscape= out of memory

converted PSI to GEXF , the networks can be openeded in gephi

<?xml version='1.0'  encoding="UTF-8" ?>
<xsl:stylesheet
	xmlns:g="http://www.gexf.net/1.2draft"
        xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
	xmlns:p="net:sf:psidev:mi"
        version='1.0'
        >
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
<g:gexf  version="1.2">
<xsl:apply-templates select="p:entrySet"/>
</g:gexf>
</xsl:template>


<xsl:template match="p:entrySet">
<xsl:apply-templates select="p:entry"/>
</xsl:template>

<xsl:template match="p:entry">
  <g:graph mode="static" defaultedgetype="undirected">
	<g:nodes>
	<xsl:apply-templates select="p:interactorList"/>
	</g:nodes>
  </g:graph>
</xsl:template>


<xsl:template match="p:entry">
  <g:graph mode="static" defaultedgetype="directed">
    <xsl:apply-templates select="p:interactorList"/>
    <xsl:apply-templates select="p:interactionList"/>
  </g:graph>
</xsl:template>

<xsl:template match="p:interactorList">
<g:nodes>
  <xsl:apply-templates select="p:interactor"/>
</g:nodes>
</xsl:template>

<xsl:template match="p:interactor">
  <xsl:element name="g:node">
    <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
    <xsl:attribute name="label"><xsl:value-of select="p:names/p:shortLabel"/></xsl:attribute>
  </xsl:element>
</xsl:template>

<xsl:template match="p:interactionList">
<g:edges>
  <xsl:apply-templates select="p:interaction"/>
</g:edges>
</xsl:template>

<xsl:template match="p:interaction">
  <xsl:element name="g:edge">
    <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
    <xsl:attribute name="source"><xsl:value-of select="p:participantList/p:participant[1]/p:interactorRef"/></xsl:attribute>
    <xsl:attribute name="target"><xsl:value-of select="p:participantList/p:participant[2]/p:interactorRef"/></xsl:attribute>
  </xsl:element>
</xsl:template>


</xsl:stylesheet>

But it's slow & not very useful. I transformed the PSI to GXMML with the following xslt stylesheet:

<?xml version='1.0'  encoding="UTF-8" ?>
<xsl:stylesheet
        xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
	xmlns:dc="http://purl.org/dc/elements/1.1/"
	xmlns:xlink="http://www.w3.org/1999/xlink"
	xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
	xmlns:cy="http://www.cytoscape.org"
	xmlns="http://www.cs.rpi.edu/XGMML"  
	xmlns:p="net:sf:psidev:mi"
        version='1.0'
        >
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/">
<xsl:apply-templates select="p:entrySet"/>
</xsl:template>


<xsl:template match="p:entrySet">
<xsl:apply-templates select="p:entry"/>
</xsl:template>


<xsl:template match="p:entry">
  <graph directed="0" label="Network">
    <att name="documentVersion" value="1.1"/>
  <att name="networkMetadata">
    <rdf:RDF>
      <rdf:Description rdf:about="">
	<dc:type>Protein-Protein Interaction</dc:type>
	<dc:description>N/A</dc:description>
	<dc:identifier>N/A</dc:identifier>
	<dc:date>2011-01-31 10:37:20</dc:date>
	<dc:title>Network</dc:title>
	<dc:source>http://www.cytoscape.org/</dc:source>
	<dc:format>Cytoscape-XGMML</dc:format>
      </rdf:Description>
    </rdf:RDF>
  </att>

    <xsl:apply-templates select="p:interactorList"/>
    <xsl:apply-templates select="p:interactionList"/>
  </graph>
</xsl:template>

<xsl:template match="p:interactorList">
  <xsl:apply-templates select="p:interactor"/>
</xsl:template>

<xsl:template match="p:interactor">
  <xsl:element name="node">
    <xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
    <xsl:attribute name="label"><xsl:value-of select="p:names/p:shortLabel"/></xsl:attribute>
  </xsl:element>
</xsl:template>

<xsl:template match="p:interactionList">
  <xsl:apply-templates select="p:interaction"/>
</xsl:template>

<xsl:template match="p:interaction">
  <xsl:element name="edge">
    <xsl:attribute name="source"><xsl:value-of select="p:participantList/p:participant[1]/p:interactorRef"/></xsl:attribute>
    <xsl:attribute name="target"><xsl:value-of select="p:participantList/p:participant[2]/p:interactorRef"/></xsl:attribute>
    <xsl:attribute name="label"><xsl:value-of select="p:names/p:shortLabel"/></xsl:attribute>
  </xsl:element>
</xsl:template>


</xsl:stylesheet>

Again... too much information...